calcul de la puissance d une machine à vapeur

[rexacont]

SALUT
formule4 variables
W=SxC x N/60 x10^4/75 xP x2
alesage S course C N RPM P pression
merci

[3E0_RTN]

Version riche pour HP-41C :

01 LBL 'W
02 'S?
03 PROMPT
04 'C?
05 PROMPT
05 x
06 'N?
07 PROMPT
08 x
09 .225
10 /
11 'P?
12 PROMPT
13 x
14 FIX 4
15 'W=
16 ARCL x
17 PROMPT
18 RTN

[3E0_RTN]

Version moins riche (pour HP-33E par exemple) :

Pile :
T = S
Z = C
Y = N
X = P

Programme :
01 x
02 x
03 x
04 .
05 2
06 2
07 5
08 /

[hpmaniac]

Version très riche pour HP-41C: ce programme permet de calculer la valeur de n’importe laquelle des 5 variables à partir des 4 autres. Il est inspiré du programme TVM du module Advantage.

Le calcul de n’importe quelle variable suit le même principe: on entre les valeurs de chacune des variables connues, suivi de la touche correspondant sur la première rangée ; puis sans entrer de valeur on appuie sur la touche correspondant à la variable que l’on cherche. Le programme fait le calcul et affiche la valeur recherchée.

Exemple d’utilisation pour calculer la puissance W:

• XEQ “PUISS” pour lancer l’exécution
• La machine passe en mode User et un menu s’affiche: “S C N P W”, chaque lettre correspond à une des touches de la rangée du haut
• Entrer la valeur de S puis appuyer sur la touche ?+, la machine affiche S= “valeur“, (on peut ensuite appuyer sur R /S pour réafficher le menu ou poursuivre directement)
• Entrer la valeur de C puis appuyer sur la touche 1/x, la machine affiche C= “valeur“, (on peut ensuite appuyer sur R /S pour réafficher le menu ou poursuivre directement)
• Entrer la valeur de N puis appuyer sur la touche ?x, la machine affiche N= “valeur“, (on peut ensuite appuyer sur R /S pour réafficher le menu ou poursuivre directement)
• Entrer la valeur de P puis appuyer sur la touche LOG, la machine affiche P= “valeur“, (on peut ensuite appuyer sur R /S pour réafficher le menu ou poursuivre directement)
• Appuyer sur la touche LN sans entrer de valeur, la machine calcule W puis affiche W=“valeur“

Note1: pour que ce programme fonctionne correctement, il ne doit y avoir aucune assignation sur la première rangée de touches.
Note2: une fois les valeurs rentrées, si l'on veut effectuer un nouveau calcul, il n'est pas nécessaire de rentrer à nouveau les valeurs qui ne changent pas. Par exemple si on veut calculer la puissance pour différentes valeurs de N, les autres variables étant constantes, il suffit après le premier calcul de rentrer la nouvelle valeur de N, d'appuyer sur la touche ?x, puis sur la touche LN pour avoir la nouvelle valeur de la puissance W.
Note3: ligne 10 le caractère ~ correspond au symbole "Append" (SHIFt XEQ en mode Alpha)

Code : Tout sélectionner

 01  LBL “PUISS"  
02  CLx  
03  STO 01                  S
04  STO 02                  C
05  STO 03                  N
06  STO 04                  P
07  STO 05                  W
08  GTO 00  
09  LBL 09                  Afichage de la valeur entrée ou calculée
10  “~=  
11  ARCL X  
12  AVIEW  
13  LBL 00                  Affichage du menu
14  SF 27  
15  CF 22  
16  “S  C  N  P W”  
17  PROMPT  
18  GTO 00  
19  LBL A                   Choix 'S'
20  “S  
21  STO 01  
22  FC?C 22  
23  XEQ 01  
24  GTO 09  
25  LBL B                   Choix 'C'
26  “C  
27  STO 02  
28  FC?C 22  
29  XEQ 02  
30  GTO 09  
31  LBL C                   Choix 'N'
32  “N  
33  STO 03  
34  FC?C 22  
35  XEQ 03  
36  GTO 09   
37  LBL D                   Choix 'P'
38  “P  
39  STO 04  
40  FC?C 22  
41  XEQ 04  
42  GTO 09  
43  LBL E                   Choix 'W'
44  “W  
45  STO 05  
46  FC?C 22  
47  XEQ 05  
48  GTO 09  
49  LBL 01                  Calcul 'S'
50  RCL 02  
51  RCL 03  
52  RCL 04  
53  XEQ a  
54  STO 01  
55  RTN  
56  LBL 02                  Calcul 'C'
57  RCL 01  
58  RCL 03  
59  RCL 04  
60  XEQ a  
61  STO 02  
62  RTN  
63  LBL 03                  Calcul 'N'
64  RCL 01  
65  RCL 02  
66  RCL 04  
67  XEQ a  
68  STO 03  
69  RTN  
70  LBL 04                  Calcul 'P'
71  RCL 01  
72  RCL 02  
73  RCL 03  
74  XEQ a  
75  STO 04  
76  RTN  
77  LBL 05                  Calcul 'W'
78  RCL 01  
79  RCL 02  
80  *  
81  RCL 03  
82  *  
83  RCL 04  
84  *  
85  .225  
86  /  
87  STO 05  
88  RTN  
89  LBL a                   Calcul commun
90  *  
91  *  
92  .225  
93  /  
94  RCL 05  
95  X<>Y  
96  /  
97  RTN  

[3E0_RTN]

Mes ficelles de caleçon, pardon mes félicitations!
Un mot, un geste et hpmaniac fait le reste!